WinBatch Tech Support Home

Database Search

If you can't find the information using the categories below, post a question over in our WinBatch Tech Support Forum.

TechHome

Examples

Can't find the information you are looking for here? Then leave a message over on our WinBatch Tech Support Forum.

;tech support url
turl="http://techsupt.winbatch.com/webcgi/webbatch.exe?techsupt/techsupt.web"
;search url
surl="http://techsupt.winbatch.com/webcgi/webbatch.exe?techsupt/techsrch.web"
;image url header
iurl="http://techsupt.winbatch.com/gif/"

WebOut("Content-type: text/html", 2)
WebOut("<HTML>",1)


;Subdirectories under this point are part of the text support
;stuff.  Basically lots of txt files in lots of subdirectories
DirChange("TECHSUPT\TECH SUPPORT")
cmdline=WebCmdData()
ParseData(cmdline)
if param0>0 then level=strtrim(param1)
            else level=""
if param0>1 then dafile=strtrim(param2)
            else dafile=""

headtit=""           
if level!=""
   levc=strlen(level)
   for x=1 to levc by 2
      a=strsub(level,x,2)
      dd=DirItemize("*.*")
      ddx=ItemExtract(a,dd,@tab)
      DirChange(ddx)
      headtit=strcat(headtit,"/%ddx%")
   next
endif
heading=strcat("TechSupport",headtit) 
title=strcat("WWW Tech Support",headtit)


if dafile==""
   WebOut("<HEAD>",1)
   WebOut("<TITLE>",1)
   WebOut(title,1)
   WebOut("</TITLE>",1)
   WebOut("</HEAD>",1)
   WebOut("<BODY>",1)
   gosub topsy
   WebOut("%heading%<hr>",1)

   d=DirItemize("*.*")
   dc=ItemCount(d,@tab)
   for x=1 to dc
      dd=ItemExtract(x,d,@tab) 
      if x<10 then xx="0%x%"
      else xx=x
      line=`<a href="%turl%+%level%%xx%">%dd%</a><br>`
      WebOut(line,1)
   next
   d=FileItemize("*.*")
   dc=ItemCount(d,@tab)
   for x=1 to dc
      dd=ItemExtract(x,d,@tab)
      ddx=strreplace(dd," ","~")
      dd=strsub(dd,1,strlen(dd)-4) 
      line=`<a href="%turl%+%level%+%ddx%">%dd%</a><br>`
      WebOut(line,1)
   next
   gosub bottom
   WebOut("</BODY>",1)
else
   dafile=strreplace(dafile,"~"," ")
   WebOut("<HEAD>",1)
   WebOut("<TITLE>",1)
   WebOut(strcat(title,"\",dafile),1)
   WebOut("</TITLE>",1)
   WebOut("</HEAD>",1)
   WebOut("<BODY>",1)
   gosub topsy
   
   
   WebOut(strcat(heading,"\",dafile,"<HR>"),1)
   WebOutFile(dafile)
   gosub bottom
   WebOut("</BODY>",1)

endif

WebOut("</HTML>",1)
exit

:topsy
WebOut(`<IMG SRC="%iurl%gr-techsupport.GIF" BORDER="0" WIDTH="174" HEIGHT="191" HSPACE="24" VSPACE="0" ALIGN="right" ALT="Our (nearly) psychic tech support">`,1)

WebOut(`<IMG SRC="%iurl%main-logo.GIF" BORDER="0" WIDTH="348" HEIGHT="36" HSPACE="0" VSPACE="12" ALT="[logo] Wilson WindowWare"><p>`,1)     

return


:bottom
WebOut(`<HR>If you're trying to find specific info and don't know where to start, try typing some keywords into our handy Search Engine.<P>`,1)
if level=="" then levxx="xx"
             else levxx=level
headxx=strreplace(heading," ","~")             
WebOut(`<Form method=POST action="%surl%+%levxx%+%headxx%">`,1)
WebOut(`Keyword(s) to <Strong>search</Strong> for:<BR>`,1)
WebOut(`<Input TYPE="text" NAME="keywords" SIZE=60><P>`,1)
WebOut(`<Input TYPE="radio" NAME="scope" VALUE="all" CHECKED>`,1)
WebOut(`Search in all areas<BR>`,1)
WebOut(`<Input TYPE="radio" NAME="scope" VALUE="%level%">`,1)
WebOut(`Search in '%heading%'<P>`,1)
WebOut(`<Input TYPE="radio" NAME="anyall" VALUE="any" CHECKED>`,1)
WebOut(`Match <Strong>any</Strong> of the specified keywords<BR>`,1)
WebOut(`<Input TYPE="radio" NAME="anyall" VALUE="all">`,1)
WebOut(`Match <Strong>all</Strong> of the specified keywords<P>`,1)
;WebOut(`<Input TYPE="checkbox" NAME="matchcase" VALUE="Yes">`,1)
;WebOut(`Case-sensitive search<BR>`,1)
;WebOut(`<Input TYPE="checkbox" NAME="wholeword" VALUE="Yes">`,1)
;WebOut(`Match whole words<P>`,1)
WebOut(`<Input TYPE="submit" VALUE="Start search">`,1)
WebOut(`<Input TYPE="reset" VALUE="Reset form"><P>`,1)
WebOut(`</Form>`,1)
WebOut(`<HR>Or, if you can't find the information you want anywhere, you can try emailing <A HREF="mailto:support@windowware.com">support@windowware.com</a>`,1)
return


Article ID:   W12470
Filename:   Example Part 1 techsupt.web.txt
File Created: 2017:08:29:10:33:18
Last Updated: 2017:08:29:10:33:18