WinBatch Tech Support Home

Database Search

If you can't find the information using the categories below, post a question over in our WinBatch Tech Support Forum.

TechHome

WinBatch
Mouse and Cursor Topics

Can't find the information you are looking for here? Then leave a message over on our WinBatch Tech Support Forum.

Disable Working in Background Cursor

 Keywords: disable enable working background arrow hourglass 
Posted to Webboard - WinBatch Script Exchange  
From:  ferchl 
Date:  Tuesday, December 04, 2008 7:44 AM  

; User defined subroutines to disable/enable the "working in background"
; (aka AppStarting) cursor (e.g. mouse pointer with hourglass).
; These routines must run in the user session

; Disable "Working in Background" (aka AppStarting) cursor
#DefineSubRoutine NoBusyCursor()
MyPath = DirScript()
NormalCursor = MyPath:"Normal.cur"
CursorsReg = "Control Panel\Cursors"
ArrowReg = CursorsReg:"[Arrow]"
AppStartingReg = CursorsReg:"[AppStarting]"
ErrMode = ErrorMode(@OFF)
Arrow = StrTrim(RegQueryExpSz(@REGCURRENT,ArrowReg))
AppStarting = StrTrim(RegQueryExpSz(@REGCURRENT,AppStartingReg))
ErrorMode(ErrMode)
If Arrow=="0" Then Arrow = ""
If AppStarting=="0" Then AppStarting = ""
If Arrow=="" Then NewCursor = NormalCursor
Else NewCursor = Arrow
RegSetExpSz(@REGCURRENT,ArrowReg,NewCursor)
RegSetExpSz(@REGCURRENT,AppStartingReg,NewCursor)
SysParamInfo(87,"",2)
#EndSubRoutine

; Restore "Working in Background" (aka AppStarting) cursor
#DefineSubRoutine RestoreBusyCursor()
RegSetExpSz(@REGCURRENT,ArrowReg,Arrow)
RegSetExpSz(@REGCURRENT,AppStartingReg,AppStarting)
SysParamInfo(87,"",2)
#EndSubRoutine

; Test
NoBusyCursor()
Message("Busy cursor disabled","Try launching something and you should see no cursor change")
RestoreBusyCursor()
Message("Busy cursor restored","Previous working in background cursor should now be in effect")

Article ID:   W17986

Filename:   Disable Working in Background Cursor.txt
File Created: 2008:12:04:09:17:26
Last Updated: 2008:12:04:09:17:26