Database Search
If you can't find the information using the categories below, post a question over in our WinBatch Tech Support Forum.
TechHome
Install Apps with WB Example
Can't find the information you are looking for here? Then leave a message over on our WinBatch Tech Support Forum.
Sample Installation Script
; Title: user directed installation of software.
; Author: Jim Stiles, May 2003
; Method
; 1. A dialog is made with prebuilt controls. These are:
; a. Headline
; b. Caption
; c. Multiline editbox for display of large amounts of text.
; d. Single line editbox for display for single line text entry.
; e. Change button for user editing control. This button is not used in this example.
; f. Static text boxes (2) for showing progress. Progress display is done by showing ASCII 149 characters: the blip or •.
; g. A back button handles changes of mind by user.
; h. A next button advances the script.
; i. A quit button that quits the script.
; This dialog appears at the upper left of the screen to allow other dialogs center stage.
; Most of the action in this script is initiated by the user clicking pushbuttons: Back Next and Quit.
; A counter, iTaskCounter, keeps track of each step in this script.
; A function, dlgReset(), sets all controls off. \
; In each step, dlgReset() turns all controls off, then specific DialogConbtrolState functions turn on specific controls.
; This procedure allows the Back button to perform as expected. It also makes it a simple matter to clear unwanted controls in any dialog.
;;;;; Initialization ;;;;;
IntControl(49,1,0,0,0)
;;;;; Dialog Box ;;;;;
DistriCFormat=`WWWDLGED,6.1`
DistriCCaption=`Distri/Pak`
DistriCX=010
DistriCY=010
DistriCWidth=364
DistriCHeight=242
DistriCNumControls=015
DistriCProcedure=`DistriC`
DistriCFont=`Arial|7680|40|34`
DistriCTextColor=`0|0|0`
DistriCBackground=`DEFAULT,212|212|212`
DistriCConfig=2
DistriC001=`023,005,324,015,VARYTEXT,MyVariable1,"Headline",DEFAULT,15,DEFAULT,"Times New Roman|9728|70|18","0|0|0","255|255|255"`
DistriC002=`023,029,324,044,VARYTEXT,MyVariable2,"Text Display",DEFAULT,4,DEFAULT,"Arial|7680|40|34","0|0|0",DEFAULT`
DistriC003=`023,145,056,012,RADIOBUTTON,MyRadioVar,"I agree.",1,6,DEFAULT,DEFAULT,DEFAULT,DEFAULT`
DistriC004=`083,145,200,012,RADIOBUTTON,MyRadioVar,"I do not agree. I will cancel this installation.",2,7,DEFAULT,DEFAULT,DEFAULT,DEFAULT`
DistriC005=`023,187,324,022,GROUPBOX,DEFAULT,"Task Progress",DEFAULT,2,DEFAULT,DEFAULT,DEFAULT,DEFAULT`
DistriC006=`023,077,324,050,MULTILINEBOX,MyVariable4,"Multiline text",DEFAULT,1,DEFAULT,DEFAULT,DEFAULT,"255|255|255"`
DistriC007=`303,145,044,012,PUSHBUTTON,DEFAULT,"&Change",2,8,DEFAULT,DEFAULT,DEFAULT,DEFAULT`
DistriC008=`201,219,044,012,PUSHBUTTON,DEFAULT,"< &Back",1,5,DEFAULT,DEFAULT,DEFAULT,DEFAULT`
DistriC009=`251,219,044,012,PUSHBUTTON,DEFAULT,"&Next >",3,9,DEFAULT,DEFAULT,DEFAULT,DEFAULT`
DistriC010=`301,219,044,012,PUSHBUTTON,DEFAULT,"&Quit",4,10,DEFAULT,DEFAULT,DEFAULT,DEFAULT`
DistriC011=`023,159,324,024,GROUPBOX,DEFAULT,"Overall Progress",DEFAULT,2,DEFAULT,DEFAULT,DEFAULT,DEFAULT`
DistriC012=`029,197,312,008,STATICTEXT,DEFAULT,"",DEFAULT,12,DEFAULT,"Arial|9728|70|34","255|0|0","255|255|255"`
DistriC013=`029,171,312,008,STATICTEXT,DEFAULT,"",DEFAULT,12,DEFAULT,"Arial|9728|70|34","255|0|0","255|255|255"`
DistriC014=`023,131,324,012,EDITBOX,MyVariable5,"Single line text",DEFAULT,14,DEFAULT,DEFAULT,DEFAULT,"255|255|255"`
DistriC015=`001,001,358,020,STATICTEXT,DEFAULT,DEFAULT,DEFAULT,3,DEFAULT,DEFAULT,DEFAULT,"255|255|255"`
ButtonPushed=Dialog("DistriC",0) ; WinBatch will not display this dialog.
;;;; SubRoutines ;;;;;
#DefineSubRoutine DistriC(DistriC_Handle,DistriC_Message,DistriC_ID,rsvd1,rsvd2)
;DialogprocOptions Constants
MSG_INIT=0 ; The one-time initilization
MSG_TIMER=1 ; Timer event
MSG_BUTTONPUSHED=2 ; Pushbutton or Picturebutton
MSG_RADIOPUSHED=3 ; Radiobutton clicked
MSG_CHECKBOX=4 ; Checkbox clicked
MSG_EDITBOX=5 ; Editbox or Multilinebox
MSG_FILESELECT=6 ; Filelistbox
MSG_ITEMSELECT=7 ; Itembox
MSG_COMBOCHANGE=8 ; Combobox/Droplistbox
MSG_CALENDAR=9 ; Calendar date change
MSG_SPINNER=10 ; Spinner number change
MSG_CLOSEVIA49=11 ; Close clicked (Enabled via Intcontrol 49)
MSG_FILEBOXDOUBLECLICK=12 ; Get double-click message on a FileListBox
MSG_ITEMOXDOUBLECLICK=13 ; Get double-click message on an ItemBox
DPO_DISABLESTATE=1000 ; codes -1=GetSetting 0=EnableDialog 1=DisableDialog
DPO_CHANGEBACKGROUND=1001 ; -1=GetSetting otherise bitmap or color string
;DialogControlState Constants
DCSTATE_SETFOCUS=1 ; Give Control Focus
DCSTATE_QUERYSTYLE=2 ; Query control's style
DCSTATE_ADDSTYLE=3 ; Add control style
DCSTATE_REMOVESTYLE=4 ; Remove control style
DCSTATE_GETFOCUS=5 ; Get control that has focus
DCSTYLE_INVISIBLE=1 ; Set Control Invisible
DCSTYLE_DISABLED=2 ; Set Control Disabled
DCSTYLE_NOUSERDATA=4 ; Note: Setable via DialogControlState function ONLY SPINNER control only
DCSTYLE_READONLY=8 ; Sets control to read-only (user cannot type in data) EDITBOX MULTILINEBOX SPINNER
DCSTYLE_PASSWORD=16 ; Sets 'password mode' where only *'s are displayed EDITBOX
DCSTYLE_DEFAULTBUTTON=32 ; Sets a button as a the default button PUSHBUTTON PICTUREBUTTON
DCSTYLE_DIGITSONLY=64 ; Set edit box to accept digits only EDITMOX MULTILINEBOX
DCSTYLE_FLAT=128 ; Makes a 'flat' hyperlink-looking button PUSHBUTTON PICTUREBUTTON
;DialogControlSet / DialogControlGet Constants
DC_CHECKBOX=1 ; CHECKBOX
DC_RADIOBUTTON=2 ; RADIOBUTTON
DC_EDITBOX=3 ; EDITBOX MULTILINEBOX
DC_TITLE=4 ; PICTURE RADIOBUTTON CHECKBOX PICTUREBUTTON VARYTEXT STATICTEXT GROUPBOX PUSHBUTTON
DC_ITEMBOXCONTENTS=5 ; ITEMBOX FILELISTBOX DROPLISTBOX
DC_ITEMBOXSELECT=6 ; ITEMBOX FILELISTBOX DROPLISTBOX
DC_CALENDAR=7 ; CALENDAR
DC_SPINNER=8 ; SPINNER
DC_MULTITABSTOPS=9 ; MULTILINEBOX
DC_ITEMSCROLLPOS=10 ; ITEMBOX FILELISTBOX
DC_BACKGROUNDCOLOR=11 ; RADIOBUTTON CHECKBOX VARYTEXT STATICTEXT GROUPBOX PUSHBUTTON ITEMBOX FILELISTBOX DROPLISTBOX SPINNER EDITBOX MULTILINEBOX
DC_PICTUREBITMAP=12 ; PICTURE PICTUREBUTTON
DC_TEXTCOLOR=13 ; RADIOBUTTON CHECKBOX VARYTEXT STATICTEXT GROUPBOX PUSHBUTTON ITEMBOX FIELLISTBOX DROPLISTBOX SPINNER EDITBOX MULTILINEBOX
DC_ITEMBOXADD=14 ; ITEMBOX FILELISTBOX DROPLISTBOX
DC_ITEMBOXREMOVE=15 ; ITEMBOX FILELISTBOX DROPLISTBOX
Switch DistriC_Message
Case MSG_INIT
; DialogProcOptions(DistriC_Handle,MSG_TIMER,1000)
dlgReset()
myHeadline = "Distri/Pak Software Installation Module"
myText = "We have exciting news today! New updates to WinBatch have arrived and are ready to install."
myText = StrCat(myText,@CRLF,@CRLF,"Click the Next button to begin.")
;myText = StrCat(myText,@CRLF,"")
DialogProcOptions(DistriC_Handle,MSG_BUTTONPUSHED,@TRUE) ; Always detect a button push.
DialogProcOptions(DistriC_Handle,MSG_RADIOPUSHED,@FALSE); Do not detect a click on a radio button.
DialogProcOptions(DistriC_Handle,MSG_EDITBOX,@FALSE) ; Do not detect data character entry. Wait to handle this editbox with a pushbutton.
DialogProcOptions(DistriC_Handle,MSG_CLOSEVIA49,@TRUE)
DialogControlSet(DistriC_Handle,1,DC_Title,myHeadline) ; Headline.
DialogControlSet(DistriC_Handle,2,DC_Title,myText) ; Display text.
DialogControlState(DistriC_Handle,9,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Next button.
;DialogControlState(DistriC_Handle,8,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Back button.
;DialogControlState(DistriC_Handle,10,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Quit button.
;DialogControlState(DistriC_Handle,3,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Show Radio 1.
;DialogControlState(DistriC_Handle,4,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Show Radio 2.
;DialogControlState(DistriC_Handle,6,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Show Multiline text display or entry.
;DialogControlState(DistriC_Handle,7,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Show Change button.
;DialogControlState(DistriC_Handle,11,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Show Overall progress group box.
;DialogControlState(DistriC_Handle,12,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Show Task progress indicator.
;DialogControlState(DistriC_Handle,5,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Show Task progress group box.
;DialogControlState(DistriC_Handle,13,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Show Overall progress indicator.
;DialogControlState(DistriC_Handle,14,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Show Single line edit box for data collection from user.
iTaskCounter = iTaskCounter + 1
Return(-1)
Case MSG_BUTTONPUSHED
Switch DistriC_ID ; ID number of pushbutton user clicks
Case 007 ; Change button.
myHeadline = "Select a folder"
myText = "Enter a new folder or keep the default. "
myText = StrCat(myText,@CRLF,@CRLF,"Click Next to continue.")
DialogControlSet(DistriC_Handle,1,DC_Title,myHeadline) ; Headline.
DialogControlSet(DistriC_Handle,2,DC_Title,myText) ; Display text.
iTaskCounter = ITaskCounter - 1
Return(-2)
Case 008 ; < Back button.
dlgReset()
DialogControlState(DistriC_Handle,9,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Next button.
iTaskCounter = iTaskCounter -2
If iTaskCounter <1 Then iTaskCounter = 1
;No return handling here. The script continues with the following section for the 'Next >' button.
Case 009 ; Next > button. Most of the action takes place here. Next and Back will cycle through these case statements in order.
Switch iTaskCounter
Case 1 ; License agreement
dlgReset()
myTest = @FALSE
;; Show headline and caption
myHeadline = "Step 1: Licensing"
myText = "You must agree to this license to use this software. "
myText = StrCat(myText,@CRLF,@CRLF,"Click Next to continue.")
DialogControlSet(DistriC_Handle,1,DC_Title,myHeadline) ; Headline.
DialogControlSet(DistriC_Handle,2,DC_Title,myText) ; Display text.
;; Show controls
DialogControlState(DistriC_Handle,9,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Next button.
DialogControlState(DistriC_Handle,8,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Back button.
DialogControlState(DistriC_Handle,10,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Quit button.
DialogControlState(DistriC_Handle,3,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Radio 1.
DialogControlState(DistriC_Handle,4,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Radio 2.
DialogControlState(DistriC_Handle,6,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Multiline text display or entry.
DialogControlSet(DistriC_Handle,6, DC_EDITBOX,slicenseText) ; Put text into box.
DialogControlSet(DistriC_handle,6,DC_ITEMSCROLLPOS,1); Move cursor to first line in box.
DialogControlSet(DistriC_Handle,3, DC_TITLE,"I agree.")
DialogControlSet(DistriC_Handle,4, DC_TITLE,"I do not agree and want to quit.")
iTaskCounter = ITaskCounter + 1
Return (-2) ; Continue
Case 2 ; Handle license agreement check.
;; Hide controls
DialogControlSet(DistriC_Handle,2,DC_Title,myText) ; Display text.
dlgReset()
DialogControlState(DistriC_Handle,9,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Next button.
DialogControlState(DistriC_Handle,8,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Back button.
DialogControlState(DistriC_Handle,10,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Quit button.
;; Test licensing decision
myTest = DialogControlGet(DistriC_handle,3,DC_RADIOBUTTON)
If myTest == @FALSE
DialogControlState(DistriC_Handle,9,DCSTATE_ADDSTYLE, DCSTYLE_INVISIBLE)
myHeadline = "License Refused"
myText = "You must agree to this license to use this software. "
myText = StrCat(myText,@CRLF,@CRLF,"Click Back to try again or Quit, to quit.")
DialogControlSet(DistriC_Handle,1,DC_Title,myHeadline) ; Headline.
iTaskCounter = 1
Else
myHeadline = "License Accepted"
myText = "You agree to the license. "
myText = StrCat(myText,@CRLF,@CRLF,"Click Next to continue, Back to reconsider, or Quit to exit.")
DialogControlSet(DistriC_Handle,1,DC_Title,myHeadline) ; Headline.
DialogControlSet(DistriC_Handle,2,DC_Title,myText) ; Display text.
iTaskCounter = iTaskCounter + 1
EndIf
Return (-2)
Case 3 ; Choose an installation folder
;; Hide controls
dlgReset()
;; Show controls
DialogControlState(DistriC_Handle,9,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Next button.
DialogControlState(DistriC_Handle,8,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Back button.
DialogControlState(DistriC_Handle,10,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Quit button.
DialogControlState(DistriC_Handle,14,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Single line edit box for data collection from user.
DialogControlSet(DistriC_Handle,14,DC_EDITBOX,"c:\program files\myapp")
;; Show headline and caption
myHeadline = "Step 2. Specify a folder for the installed software."
myText = "The suggested folder for this software installation is "
myText = StrCat(myText,@CRLF,@CRLF,"c:\program files\myapp")
myText = StrCat(myText,@CRLF,@CRLF, "To change this, enter a new path and click Next.")
myText = StrCat(myText,@CRLF,@CRLF, "To accept this path, click Next.")
DialogControlSet(DistriC_Handle,1,DC_Title,myHeadline) ; Headline.
DialogControlSet(DistriC_Handle,2,DC_Title,myText) ; Display text.
iTaskCounter = ITaskCounter + 1
Return (-2) ; Continue
Case 4 ; Folder selection
dlgReset()
DialogControlState(DistriC_Handle,9,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Next button.
DialogControlState(DistriC_Handle,8,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Back button.
DialogControlState(DistriC_Handle,10,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Quit button.
myFolder = DialogControlGet(DistriC_Handle,14,DC_EDITBOX)
DialogControlState(DistriC_Handle,14,DCSTATE_ADDSTYLE, DCSTYLE_INVISIBLE) ; Single line edit box for data collection from user.
;; Show headline and caption
myHeadline = "Folder Selection"
myText = "You selected the folder: "
myText = StrCat(myText,@CRLF,@CRLF,myFolder)
myText = StrCat(myText,@CRLF,@CRLF, "To change this, click Back and try again.")
myText = StrCat(myText,@CRLF,@CRLF, "To accept this folder, click Next.")
DialogControlSet(DistriC_Handle,1,DC_Title,myHeadline) ; Headline.
DialogControlSet(DistriC_Handle,2,DC_Title,myText) ; Display text.
iTaskCounter = iTaskCounter + 1
Return (-2)
Case 5 ; Check for file
; Hide controls
dlgReset()
DialogControlState(DistriC_Handle,9,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Next button.
DialogControlState(DistriC_Handle,8,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Back button.
DialogControlState(DistriC_Handle,10,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Quit button.
; Headline and caption.
myHeadline = "System Test"
myText = "Computer settings need to be verified."
myText = StrCat(myText,@CRLF,@CRLF,"Please wait while your settings are checked. Click Next to continue.")
DialogControlSet(DistriC_Handle,1,DC_Title,myHeadline) ; Headline.
DialogControlSet(DistriC_Handle,2,DC_Title,myText) ; Display text.
myFileFind = FileLocate('win.ini')
If myFileFind == ''
myHeadline = 'Problem found with system file configuration."
DialogControlSet(DistriC_Handle,1,DC_Title,myHeadline) ; Headline.
myText = "No win.ini file found. This job will quit. Please quit and inform your system administrator."
DialogControlSet(DistriC_Handle,2,DC_Title,myText) ; Display text.
Message("Error" , "Incorrect PC setup values. Call administrator. Click OK to exit." )
Return(0)
EndIf
iTaskCounter = ITaskCounter + 1
Return (-2) ; Continue
Case 6 ; Installation tasks go here.
; Maximum number of blips, progress indicators, is 50. Assign the amount of blips you need to show
; progress of separate tasks, as well as the entire job.
myHeadline = "Copying files."
dlgReset()
DialogControlSet(DistriC_Handle,1,DC_Title,myHeadline) ; Headline.
DialogControlState(DistriC_Handle,9,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Show Next button.
DialogControlState(DistriC_Handle,5,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Task progress group box.
DialogControlState(DistriC_Handle,11,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Overall progress group box.
DialogControlState(DistriC_Handle,12,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Task progress indicator.
DialogControlState(DistriC_Handle,13,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE) ; Overall progress indicator.
DialogControlSet(DistriC_Handle,5,DC_TITLE, "Task Progress") ; Task progress group box.
DialogControlSet(DistriC_Handle,11,DC_TITLE, "Overall Progress") ; Overall progress group box.
sTaskProg = MakeBlips(25) ; This task.
sTaskOverall = MakeBlips(6); Whole job.
DialogControlSet(DistriC_Handle,12,DC_TITLE, sTaskProg) ; Task progress indicator.
DialogControlSet(DistriC_Handle,13,DC_TITLE, sTaskOverall) ; Overall progress indicator.
TimeDelay(2)
sTaskProg = MakeBlips(50) ; This task.
sTaskOverall = MakeBlips(15) ; Whole job.
DialogControlSet(DistriC_Handle,12,DC_TITLE, sTaskProg) ; Task progress indicator.
DialogControlSet(DistriC_Handle,13,DC_TITLE, sTaskOverall) ; Overall progress indicator.
TimeDelay(2)
sTaskProg = MakeBlips(1) ; This task.
sTaskOverall = MakeBlips(30) ; Whole job.
DialogControlSet(DistriC_Handle,12,DC_TITLE, sTaskProg) ; Task progress indicator.
DialogControlSet(DistriC_Handle,13,DC_TITLE, sTaskOverall) ; Overall progress indicator.
TimeDelay(2)
sTaskProg = MakeBlips(50) ; This task.
sTaskOverall = MakeBlips(50) ; Whole job.
DialogControlSet(DistriC_Handle,12,DC_TITLE, sTaskProg) ; Task progress indicator.
DialogControlSet(DistriC_Handle,13,DC_TITLE, sTaskOverall) ; Overall progress indicator.
TimeDelay(2)
myHeadline = 'Job Complete'
DialogControlSet(DistriC_Handle,1,DC_Title,myHeadline) ; Headline.
myText = "Enjoy your new software."
DialogControlSet(DistriC_Handle,2,DC_Title,myText) ; Display text.
dlgReset()
DialogControlSet(DistriC_Handle,10, DC_TITLE,"Finished")
DialogControlState(DistriC_Handle,10,DCSTATE_REMOVESTYLE, DCSTYLE_INVISIBLE); Quit button.
TimeDelay(3)
;iTaskCounter = ITaskCounter + 1
Return (0)
EndSwitch ;DistriC_ID
Return(-1) ; Do default processing
EndSwitch ; DistriC_Message
Return(-1) ; Do default processing
#EndSubRoutine ;End of Dialog Callback DistriCCallbackProc
#DefineFunction MakeBlips(iBlips)
sBlip = Num2Char(149)
sBlips = ""
For i = 1 To iBlips
sBlips = StrCat(sBlips," ",sBlip)
Next i
Return sBlips
#EndFunction
#DefineSubRoutine dlgReset()
DialogControlState(DistriC_Handle,9,DCSTATE_ADDSTYLE, DCSTYLE_INVISIBLE); Next button.
DialogControlState(DistriC_Handle,8,DCSTATE_ADDSTYLE, DCSTYLE_INVISIBLE); Back button.
DialogControlState(DistriC_Handle,10,DCSTATE_ADDSTYLE, DCSTYLE_INVISIBLE); Quit button.
DialogControlState(DistriC_Handle,3,DCSTATE_ADDSTYLE, DCSTYLE_INVISIBLE) ; Radio 1.
DialogControlState(DistriC_Handle,4,DCSTATE_ADDSTYLE, DCSTYLE_INVISIBLE) ; Radio 2.
DialogControlState(DistriC_Handle,6,DCSTATE_ADDSTYLE, DCSTYLE_INVISIBLE) ; Multiline text display or entry.
DialogControlState(DistriC_Handle,7,DCSTATE_ADDSTYLE, DCSTYLE_INVISIBLE) ; Change button.
DialogControlState(DistriC_Handle,11,DCSTATE_ADDSTYLE, DCSTYLE_INVISIBLE) ; Overall progress group box.
DialogControlState(DistriC_Handle,12,DCSTATE_ADDSTYLE, DCSTYLE_INVISIBLE) ; Task progress indicator.
DialogControlState(DistriC_Handle,5,DCSTATE_ADDSTYLE, DCSTYLE_INVISIBLE) ; Task progress group box.
DialogControlState(DistriC_Handle,13,DCSTATE_ADDSTYLE, DCSTYLE_INVISIBLE) ; Overall progress indicator.
DialogControlState(DistriC_Handle,14,DCSTATE_ADDSTYLE, DCSTYLE_INVISIBLE) ; Single line edit box for data collection from user.
Return (1)
#EndSubRoutine
;;;;; Main Section ;;;;;
iTaskCounter = 0
sLicenseText = ""
sLicenseText = StrCat(sLicenseText,"No part of this manual may be reproduced or transmitted in any form ")
sLicenseText = StrCat(sLicenseText,@CRLF,"or by any means, electronic or mechanical, including photocopying and ")
sLicenseText = StrCat(sLicenseText,@CRLF,"recording, for any purpose without the express written permission of ")
sLicenseText = StrCat(sLicenseText,@CRLF,"Wilson WindowWare, Inc. Information in this document is subject to ")
sLicenseText = StrCat(sLicenseText,@CRLF,"change without notice and does not represent a commitment by ")
sLicenseText = StrCat(sLicenseText,@CRLF,"Wilson WindowWare, Inc.The software described herein is furnished ")
sLicenseText = StrCat(sLicenseText,@CRLF,"under a license agreement. It is against the law to copy this software ")
sLicenseText = StrCat(sLicenseText,@CRLF,"under any circumstances except as provided by the license agreement. ")
sLicenseText = StrCat(sLicenseText,@CRLF,"U.S. Government Restricted RightsUse, duplication, or disclosure by ")
sLicenseText = StrCat(sLicenseText,@CRLF,"the Government is subject to restrictions as set forth in subdivision ")
sLicenseText = StrCat(sLicenseText,@CRLF,"(b)(3)(ii) of the Rights in Technical Data and Computer Software clause ")
sLicenseText = StrCat(sLicenseText,@CRLF,"at 252.227-7013. Contractor/manufacturer is Wilson WindowWare, ")
ButtonPushed=Dialog("distriC",1)
;;;;; Exit Handling ;;;;;
:CANCEL
:oncancel
Exit
;;;;; END ;;;;;
Article ID: W16012
File Created: 2004:03:30:15:42:14
Last Updated: 2004:03:30:15:42:14