Chrome Browser History with SQLite ODBC Driver

 Keywords: Chrome Browser History ADO ADODB ADODB.Connection ADODB.Recordset SQLite SQLite3 ODBC

;Winbatch 2010C - Chrome Browser History with SQLite ODBC Driver [required]
;
;Driver download: http://www.ch-werner.de/sqliteodbc/
;
;Stan Littlefield, April 22, 2011 (not pretty but it works)
;//////////////////////////////////////////////////////////////////////////////////////


;locate places.sqlite based on user name
AddExtender("wsrch34i.dll")

BoxOpen("Please Wait","Searching For Chrome Browser History")
hand=SrchInit("C:\","History","","",16)
c=0
fnd=0
cUser=Environment("USERNAME")
While 1
   cDB=SrchNext(hand)
   If cDB=="" Then Break
   c=c+1
   If StrIndex(cDB,cUser,0,@FWDSCAN) && StrIndex(cDB,"Chrome",0,@FWDSCAN)
      fnd=1
      Break
   EndIf
EndWhile
SrchFree(hand)

cOut=DirScript():"places.txt"
If FileExist(cOut) Then FileDelete(cOut)

If fnd
   BoxText(cDB)
   ;create an ADO connection and query for sites browsed
   cConn= "DRIVER=SQLite3 ODBC Driver;Database=":cDB:";LongNames=0;Timeout=1000;NoTXN=0;SyncPragma=NORMAL;StepAPI=0;"
   oConn=CreateObject("ADODB.Connection")
   oConn.Open(cConn)
   oRS=CreateObject("ADODB.Recordset")

   ;time stamp is microseconds since January, 1601
   cSQL="SELECT url,datetime(last_visit_time/1000000-11644473600,'unixepoch','localtime') FROM urls;"

   oRS.Open(cSQL,oConn,1,3,1)
   If ! oRS.eof
      FilePut(cOut,oRS.GetString(2,,,@CRLF,))
   Else
      BoxText("Table is Empty")
      TimeDelay(2)
   EndIf
   oRS.Close()
   oRS=0
   oConn.Close()
   oConn=0
   If FileExist(cOut)
      Run("notepad.exe", cOut)
   Else
      BoxText("Error: Browser History File Could Not Be Created")
   EndIf
Else
   BoxText("Cannot Find Chrome Browser History")
EndIf
TimeDelay(2)
BoxShut()

Exit

Article ID:   W18193

Filename:   Chrome Browser History with SQLite ODBC Driver.txt

File Created: 2011:06:07:13:33:54

Last Updated: 2011:06:07:13:33:54

Database Search

TechHome

Chrome Browser History with SQLite ODBC Driver